버터백통의 N-Screen 레시피

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.events.NetStatusEvent;
import flash.geom.Rectangle;
import flash.media.Video;
import flash.net.NetConnection;
import flash.net.NetStream;
import flash.net.ObjectEncoding;

[SWF(width="550" , height="400")]
public class Video_seek_And_NetStatus extends Sprite
{
private var netc:NetConnection;
private var nets:NetStream;
private var video:Video;

private var thumb:Sprite;
private var track:Sprite;
private var progress:Sprite;
private var buffer:Sprite;
private var jump:Sprite;

private var cur:Number;
private var duration:Number;
private var isDown:Boolean;

private var meta:Object = new Object();
public function Video_seek_And_NetStatus()
{
super();

meta.onBWDone = onBWDone;
meta.onMetaData = onMeta;
meta.onCuePoint = onCue;

NetConnection.defaultObjectEncoding= ObjectEncoding.DEFAULT;
netc = new NetConnection();
netc.client = meta;
netc.addEventListener( NetStatusEvent.NET_STATUS, netStatusHandler )
netc.connect( "rtmp://211.48.55.233/upload/" );
}


private function netStatusHandler( e:NetStatusEvent ):void
{
switch (e.info.code) {
case "NetConnection.Connect.Success":
trace("Success")
nets = new NetStream( netc );
nets.client = meta;
nets.addEventListener(NetStatusEvent.NET_STATUS , onStatus );
video = new Video(500 , 375);
video.opaqueBackground = true;
video.attachNetStream( nets );
addChild( video );
nets.play("sample1");
seekPoint();
break;
case "NetStream.Play.StreamNotFound":
trace("Stream not found");
break;
}
}

private function seekPoint( ):void
{
progress = new Sprite();
track = new Sprite();
track.graphics.lineStyle(1);
track.graphics.drawRect( 10, video.height +10 - 2.5 , 450 , 5 );
track.graphics.endFill();

thumb = new Sprite();
thumb.graphics.lineStyle(1);
thumb.graphics.beginFill( 0xFFFFFF );
thumb.graphics.drawRect( 5 , video.height +10 -5 , 10 , 10 );
thumb.graphics.endFill();

buffer = new Sprite();

jump = new Sprite();
jump.graphics.beginFill( 0 , 0 );
jump.graphics.drawRect( 10, video.height +10 - 2.5 , 450 , 5 );
jump.graphics.endFill();

addChild( progress );
addChild( track );
addChild( buffer );
addChild( jump );
addChild( thumb );

addEventListener(Event.ENTER_FRAME , onEnter );
thumb.addEventListener(MouseEvent.MOUSE_DOWN , onDown );
jump.addEventListener( MouseEvent.MOUSE_DOWN , onJump );
stage.addEventListener(MouseEvent.MOUSE_UP , onUp );

}


private function onEnter( e:Event ):void
{
if( duration > 0 ){
if( isDown ){
nets.seek( (duration * thumb.x) / track.width );
}else{
thumb.x = (nets.time / duration) * track.width;
}

//빨간색으로 재생중인 구간을 보여줌
progress.graphics.clear();
progress.graphics.beginFill( 0xFF0000 );
progress.graphics.drawRect( 10, video.height +10 - 2.5 , track.x + thumb.x , 5 );
progress.graphics.endFill();
}
}

private function onJump( e:MouseEvent ):void
{
isDown = true;
nets.pause();
thumb.x = mouseX - 5 - 2.5;
nets.seek( (duration * thumb.x) / track.width );
}

private function onDown( e:MouseEvent ):void
{
isDown = true;
var rect:Rectangle = new Rectangle( 0 , 0 , track.width , 0 );
thumb.startDrag( false , rect );
nets.pause();
}

private function onUp( e:MouseEvent ):void
{
isDown = false;
thumb.stopDrag();
nets.resume();
}
private var statusCode:String;
private function onStatus( e:NetStatusEvent ):void
{
statusCode = e.info.code;
trace("************* onStatus *************")
for( var data:String in e.info ){
trace( data , " : " , e.info[data] )
}
trace("************* End *************")
//비디오가 끝나는 시점
if( e.info.code == "NetStream.Play.Stop" ){
video.clear();

}
}
private function onMeta( data:Object ):void
{
trace("onMeta" , data.duration);
duration = data.duration;
}

private function onCue( data:Object ):void
{
trace("onCue");
}
private function onBWDone( ):void
{
trace("onBWDone");
}
}
}

제가 사용한 코드입니다.
보시면 seekPoint()에서 트랙을 그리고
onEnter()에서 클릭시 nets.seek()라는 녀석이 있습니다. 매개변수는 전체 재생시간과 트랙에서의 핸들러 위치를 용해 구한 값을 설정합니다...클릭이 아닐시에는 그냥 현재 재생되는 시간에 맞게 핸들러의 x를 이동시킵니다...
여기저기 함수가 있어서 통채로 올렸습니다..
원하시는 답이 되었는지 모르겠네요...;;

플렉스 MXML에 코딩하시나 보군요~ 뭐 위의 코드는 플래시클래스이구요~ track은 단순히 재생바입니다... 바의 길이는 디자인상 고정이고.. 핸들러의 이동속도가 전체 재생시간과 바의 길이에 비례하여 이동속도를 구하여야 하구요...에러나는 코드는 플렉스UI컴포넌트를 Sprite로 사용하려고 하여 발생한것 같습니다...

도움이 되었다면 제가 기쁩니다.